Home ] Su ]
 

Integrazione verticale dell'umidità specifica

Si definisce l'umidità specifica come quantità di vapore acqueo in grammi contenuta in 1 kg di aria umida. Si esprime in grammi di vapore acqueo per chilogrammo di aria umida. Differisce poco dal rapporto di mescolanza.

Sappiamo come ricavarla con procedimento grafico dal diagramma termodinamico, conoscendo la temperatura di rugiada (td):

 

E' sufficiente considerare l'isoigrometrica (curva di uguale rapporto di mescolanza) passante per la temperatura di rugiada. Nell'esempio riportato accanto (nomogramma di Herlofson), se la temperatura di rugiada a 900 hPa è di 15°C, l'isoigrometrica che interseca detto valore restituisce una umidità specifica di 12 g/kg (rapporto di mescolanza e umidità specifica differiscono così poco che si possono utilizzare i valori dell'uno al posto dell'altro). 

Per calcolare l'umidità specifica ad un determinato livello di pressione p, possiamo adoperare la seguente formula:

 

Us = 0.622 * ( e / p )[1]


con:
e = pressione di vapore
p = pressione a cui calcoliamo l'Us

Per ottenere la pressione di vapor acqueo in hPa ad un determinato livello di pressione, possiamo utilizzare la seguente formula:

 

e = 6.11 * 10(7.5 * td / 237.7 + td)

 

con:

td = temperatura del punto di rugiada  in °C.

Con semplici calcoli, si ottiene, per una td = 15 °C, una pressione di vapore e = 17.03 hPa.

Inserendo detto valore di e nella [1], si ha un'umidità specifica di 0.012 kg/kg, che è pari a 12 g/kg.

Il modello numerico di previsione GFS (Global Forecast System), elabora per l'umidità specifica le seguenti variabili, la maggior parte delle quali presenti nel modello con risoluzione spaziale di 0.5°:

 

VariabileDescrizione abbreviata

gfs_0p50

gfs_0p25

spfhprs
 
** (1000 975 950 925 900.. 200 175 150 125 100) specific humidity [kg/kg] 
 
sino
spfh2m
 
** 2 m above ground specific humidity [kg/kg] 
 
sisi
spfh80m
 
** 80 m above ground specific humidity [kg/kg] 
 
sisi
spfh30_0mb
 
** 30-0 mb above ground specific humidity [kg/kg] 
 
sisi
spfh60_30mb
 
** 60-30 mb above ground specific humidity [kg/kg] 
 
sino
spfh90_60mb
 
** 90-60 mb above ground specific humidity [kg/kg] 
 
sino
spfh120_90mb
 
** 120-90 mb above ground specific humidity [kg/kg] 
 
sino
spfh150_120mb
 
** 150-120 mb above ground specific humidity [kg/kg] 
 
sino
spfh180_150mb
 
** 180-150 mb above ground specific humidity [kg/kg] sino

Per ottenere l'integrazione verticale dell'umidità specifica, possiamo utilizzare la funzione vint in OpenGrADS. Integriamo la variabile spfhprs su tutta la colonna d'aria fino al top dell'atmosfera. Poiché la pressione al suolo (pressfc) è fornita in Pa, è necessario dividerla per 100 per ottenere hPa.

 

'd vint(pressfc/100,spfhprs,0)'

Il risultato è l'acqua precipitabile espressa in mm.

 
* Vittorio Villasmunta
* Integrazione verticale umidità specifica
* Versione 20151108

'set display color white'
'c'
'set t 5'
palette()
'set clevs 2 4 6 8 10 12 14 16 18 20 22 24 26 28 30 32 34 36 38 40'
'set ccols 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35'

'map world'
'set mpdset hires'
'set lon 6 20'
'set lat 36 48'

* Estrazione della data e dell'ora di validità
'query time'
curtime=subwrd(result,3)
ora_v=substr(curtime,1,2)
giorno_v=substr(curtime,4,2)
mese_v=substr(curtime,6,3)
anno_v=substr(curtime,9,4)
gg_set=subwrd(result,6)
'draw title Spec Hum Vertical Integration\Valid: 'gg_set' 'giorno_v''mese_v''anno_v' at 'ora_v'Z '
'draw string 1.2 0.3 Dati GFS High Resolution - Elaborazione: V.Villasmunta'


'set grads off'
'set grid off'
'set gxout shaded'
'set csmooth on'
'd vint(pressfc/100,spfhprs,0)'
*'d vint(pressfc/100,spfhprs,0)-pwatclm'
'cbarn'
'set gxout contour'
'set csmooth on'
'set ccolor 0'
'd vint(pressfc/100,spfhprs,0)'
'printim uspec4.png'

function palette()
* These are the BLUE shades
'set rgb 16 0 0 255'
'set rgb 17 25 25 255'
'set rgb 18 50 50 255'
'set rgb 19 75 75 255'
'set rgb 20 100 100 255'
'set rgb 21 125 125 255'
'set rgb 22 150 150 255'
'set rgb 23 175 175 255'
'set rgb 24 200 200 255'
'set rgb 25 225 225 255'

* These are the RED shades
'set rgb 26 255 225 225'
'set rgb 27 255 200 200'
'set rgb 28 255 175 175'
'set rgb 29 255 150 150'
'set rgb 30 255 125 125'
'set rgb 31 255 100 100'
'set rgb 32 255 75 75'
'set rgb 33 255 50 50'
'set rgb 34 255 25 25'
'set rgb 35 255 0 0'

return


Proviamo a valutare la differenza con l'acqua precipitabile calcolata dal modello GFS (pwatclm):

 
* Vittorio Villasmunta
* Confronto Umidità specifica integrata - Acqua precipitabile
* Versione 20151108

'set display color white'
'c'
'set t 5'
'rgbset2'

'map world'
'set mpdset hires'
'set lon 6 20'
'set lat 36 48'

* Estrazione della data e dell'ora di validità
'query time'
curtime=subwrd(result,3)
ora_v=substr(curtime,1,2)
giorno_v=substr(curtime,4,2)
mese_v=substr(curtime,6,3)
anno_v=substr(curtime,9,4)
gg_set=subwrd(result,6)
'draw title Spec Hum Vertical Integration vs pwatclm\Valid: 'gg_set''giorno_v''mese_v''anno_v' at 'ora_v'Z '
'draw string 1.2 0.3 Dati GFS High Resolution - Elaborazione: V.Villasmunta'
'set grads off'
'set grid off'
'set gxout shaded'
'set csmooth on'
'd vint(pressfc/100,spfhprs,0)-pwatclm'
'cbarn'
'printim uspec5.png'

Come si può osservare, le differenze sono trascurabili (< 0.1 mm).


Questa pagina è stata realizzata da Vittorio Villasmunta

Ultimo aggiornamento: 14/05/16